libvirt/src/interface/meson.build

interface_driver_sources = [
  'interface_driver.c',
]

if conf.has('WITH_NETCF')
  interface_driver_sources += 'interface_backend_netcf.c'
endif

if conf.has('WITH_UDEV')
  interface_driver_sources += 'interface_backend_udev.c'
endif

if conf.has('WITH_INTERFACE')
  virt_modules += {
    'name': 'virt_driver_interface',
    'sources': [
      files(interface_driver_sources),
    ],
    'deps': [
      access_dep,
      libnl_dep,
      netcf_dep,
      udev_dep,
    ],
    'link_args': [
      libvirt_no_undefined,
    ],
  }

  virt_daemons += {
    'name': 'virtinterfaced',
    'c_args': [
      '-DDAEMON_NAME="virtinterfaced"',
      '-DMODULE_NAME="interface"',
    ],
  }

  virt_daemon_confs += {
    'name': 'virtinterfaced',
  }

  virt_daemon_units += {
    'service': 'virtinterfaced',
    'service_in': files('virtinterfaced.service.in'),
    'name': 'Libvirt interface',
    'sockprefix': 'virtinterfaced',
    'sockets': [ 'main', 'ro', 'admin' ],
    'conflicts': true,
  }

  openrc_init_files += {
    'name': 'virtinterfaced',
    'in_file': files('virtinterfaced.init.in')
  }

  sysconf_files += {
    'name': 'virtinterfaced',
    'file': files('virtinterfaced.sysconf'),
  }
endif