mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-11-06 13:20:20 +00:00
66 lines
2.4 KiB
Plaintext
66 lines
2.4 KiB
Plaintext
|
# gnulib-common.m4 serial 3
|
||
|
|
dnl Copyright (C) 2007 Free Software Foundation, Inc.
|
||
|
|
dnl This file is free software; the Free Software Foundation
|
||
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
||
|
|
dnl with or without modifications, as long as this notice is preserved.
|
||
|
|
|
||
|
|
# gl_MODULE_INDICATOR([modulename])
|
||
|
|
# defines a C macro indicating the presence of the given module.
|
||
|
|
AC_DEFUN([gl_MODULE_INDICATOR],
|
||
|
|
[
|
||
|
|
AC_DEFINE([GNULIB_]translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
|
||
|
|
[Define to 1 when using the gnulib module ]$1[.])
|
||
|
|
])
|
||
|
|
|
||
|
|
# AC_PROG_MKDIR_P
|
||
|
|
# is a backport of autoconf-2.60's AC_PROG_MKDIR_P.
|
||
|
|
# Remove this macro when we can assume autoconf >= 2.60.
|
||
|
|
m4_ifdef([AC_PROG_MKDIR_P], [], [
|
||
|
|
AC_DEFUN([AC_PROG_MKDIR_P],
|
||
|
|
[AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
|
||
|
|
MKDIR_P='$(mkdir_p)'
|
||
|
|
AC_SUBST([MKDIR_P])])])
|
||
|
|
|
||
|
|
# AC_C_RESTRICT
|
||
|
|
# This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
|
||
|
|
# so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
|
||
|
|
# works.
|
||
|
|
# This definition can be removed once autoconf >= 2.62 can be assumed.
|
||
|
|
AC_DEFUN([AC_C_RESTRICT],
|
||
|
|
[AC_CACHE_CHECK([for C/C++ restrict keyword], ac_cv_c_restrict,
|
||
|
|
[ac_cv_c_restrict=no
|
||
|
|
# The order here caters to the fact that C++ does not require restrict.
|
||
|
|
for ac_kw in __restrict __restrict__ _Restrict restrict; do
|
||
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
|
||
|
|
[[typedef int * int_ptr;
|
||
|
|
int foo (int_ptr $ac_kw ip) {
|
||
|
|
return ip[0];
|
||
|
|
}]],
|
||
|
|
[[int s[1];
|
||
|
|
int * $ac_kw t = s;
|
||
|
|
t[0] = 0;
|
||
|
|
return foo(t)]])],
|
||
|
|
[ac_cv_c_restrict=$ac_kw])
|
||
|
|
test "$ac_cv_c_restrict" != no && break
|
||
|
|
done
|
||
|
|
])
|
||
|
|
AH_VERBATIM([restrict],
|
||
|
|
[/* Define to the equivalent of the C99 'restrict' keyword, or to
|
||
|
|
nothing if this is not supported. Do not define if restrict is
|
||
|
|
supported directly. */
|
||
|
|
#undef restrict
|
||
|
|
/* Work around a bug in Sun C++: it does not support _Restrict, even
|
||
|
|
though the corresponding Sun C compiler does, which causes
|
||
|
|
"#define restrict _Restrict" in the previous line. Perhaps some future
|
||
|
|
version of Sun C++ will work with _Restrict; if so, it'll probably
|
||
|
|
define __RESTRICT, just as Sun C does. */
|
||
|
|
#if defined __SUNPRO_CC && !defined __RESTRICT
|
||
|
|
# define _Restrict
|
||
|
|
#endif])
|
||
|
|
case $ac_cv_c_restrict in
|
||
|
|
restrict) ;;
|
||
|
|
no) AC_DEFINE([restrict], []) ;;
|
||
|
|
*) AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
|
||
|
|
esac
|
||
|
|
])
|