From c45fed8a63d8779cfb79a9ea437f18ab58fdf665 Mon Sep 17 00:00:00 2001
From: "Daniel P. Berrange" <berrange@redhat.com>
Date: Thu, 20 Sep 2012 13:06:12 +0100
Subject: [PATCH] Convert sasl check to use LIBVIRT_CHECK_LIB_ALT

Signed-off-by: Daniel P. Berrange <berrange@redhat.com>
---
 configure.ac    | 62 ++-----------------------------------------------
 m4/virt-sasl.m4 | 29 +++++++++++++++++++++++
 2 files changed, 31 insertions(+), 60 deletions(-)
 create mode 100644 m4/virt-sasl.m4

diff --git a/configure.ac b/configure.ac
index b3e575dc3c..ffe0f66e39 100644
--- a/configure.ac
+++ b/configure.ac
@@ -156,6 +156,7 @@ AC_MSG_RESULT([$VERSION_SCRIPT_FLAGS])
 LIBVIRT_COMPILE_WARNINGS
 
 LIBVIRT_CHECK_SANLOCK
+LIBVIRT_CHECK_SASL
 LIBVIRT_CHECK_YAJL
 
 AC_MSG_CHECKING([for CPUID instruction])
@@ -1088,61 +1089,6 @@ AC_SUBST([GNUTLS_CFLAGS])
 AC_SUBST([GNUTLS_LIBS])
 
 
-dnl Cyrus SASL
-AC_ARG_WITH([sasl],
-  AC_HELP_STRING([--with-sasl], [use cyrus SASL for authentication @<:@default=check@:>@]),
-  [],
-  [with_sasl=check])
-
-SASL_CFLAGS=
-SASL_LIBS=
-if test "x$with_sasl" != "xno"; then
-  if test "x$with_sasl" != "xyes" && test "x$with_sasl" != "xcheck"; then
-    SASL_CFLAGS="-I$with_sasl"
-    SASL_LIBS="-L$with_sasl"
-  fi
-  fail=0
-  old_cflags="$CFLAGS"
-  old_libs="$LIBS"
-  CFLAGS="$CFLAGS $SASL_CFLAGS"
-  LIBS="$LIBS $SASL_LIBS"
-  AC_CHECK_HEADER([sasl/sasl.h],[],[
-    if test "x$with_sasl" = "xcheck" ; then
-        with_sasl=no
-    else
-        fail=1
-    fi])
-  if test "x$with_sasl" != "xno" ; then
-    AC_CHECK_LIB([sasl2], [sasl_client_init],[
-      SASL_LIBS="$SASL_LIBS -lsasl2"
-      with_sasl=yes
-    ],[
-      AC_CHECK_LIB([sasl], [sasl_client_init],[
-        SASL_LIBS="$SASL_LIBS -lsasl"
-        with_sasl=yes
-      ],[
-        if test "x$with_sasl" = "xcheck" ; then
-          with_sasl=no
-        else
-          fail=1
-        fi
-      ])
-    ])
-  fi
-  test $fail = 1 &&
-    AC_MSG_ERROR([You must install the Cyrus SASL development package in order to compile libvirt])
-  CFLAGS="$old_cflags"
-  LIBS="$old_libs"
-  if test "x$with_sasl" = "xyes" ; then
-    AC_DEFINE_UNQUOTED([WITH_SASL], 1,
-      [whether Cyrus SASL is available for authentication])
-  fi
-fi
-AM_CONDITIONAL([WITH_SASL], [test "x$with_sasl" = "xyes"])
-AC_SUBST([SASL_CFLAGS])
-AC_SUBST([SASL_LIBS])
-
-
 dnl DBus library
 DBUS_CFLAGS=
 DBUS_LIBS=
@@ -3039,6 +2985,7 @@ AC_MSG_NOTICE([])
 AC_MSG_NOTICE([Libraries])
 AC_MSG_NOTICE([])
 LIBVIRT_RESULT_SANLOCK
+LIBVIRT_RESULT_SASL
 LIBVIRT_RESULT_YAJL
 AC_MSG_NOTICE([  libxml: $LIBXML_CFLAGS $LIBXML_LIBS])
 AC_MSG_NOTICE([  dlopen: $DLOPEN_LIBS])
@@ -3062,11 +3009,6 @@ AC_MSG_NOTICE([  gnutls: $GNUTLS_CFLAGS $GNUTLS_LIBS])
 else
 AC_MSG_NOTICE([  gnutls: no])
 fi
-if test "$with_sasl" != "no" ; then
-AC_MSG_NOTICE([    sasl: $SASL_CFLAGS $SASL_LIBS])
-else
-AC_MSG_NOTICE([    sasl: no])
-fi
 AC_MSG_NOTICE([firewalld: $with_firewalld])
 if test "$with_avahi" = "yes" ; then
 AC_MSG_NOTICE([   avahi: $AVAHI_CFLAGS $AVAHI_LIBS])
diff --git a/m4/virt-sasl.m4 b/m4/virt-sasl.m4
new file mode 100644
index 0000000000..8fb5d7f4ff
--- /dev/null
+++ b/m4/virt-sasl.m4
@@ -0,0 +1,29 @@
+dnl The libsasl2.so or libsasl.so library
+dnl
+dnl Copyright (C) 2012-2013 Red Hat, Inc.
+dnl
+dnl This library is free software; you can redistribute it and/or
+dnl modify it under the terms of the GNU Lesser General Public
+dnl License as published by the Free Software Foundation; either
+dnl version 2.1 of the License, or (at your option) any later version.
+dnl
+dnl This library is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+dnl Lesser General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU Lesser General Public
+dnl License along with this library.  If not, see
+dnl <http://www.gnu.org/licenses/>.
+dnl
+
+AC_DEFUN([LIBVIRT_CHECK_SASL],[
+  LIBVIRT_CHECK_LIB_ALT([SASL], [sasl2],
+                        [sasl_client_init], [sasl/sasl.h],
+                        [SASL1], [sasl],
+                        [sasl_client_init], [sasl/sasl.h])
+])
+
+AC_DEFUN([LIBVIRT_RESULT_SASL],[
+  LIBVIRT_RESULT_LIB([SASL])
+])