mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-09-19 06:00:54 +00:00
130426c659
* gnulib/lib/inet_ntop.h: Remove file. * gnulib/m4/onceonly_2_57.m4: Remove file. * build-aux/useless-if-before-free: Update. * build-aux/vc-list-files: Update. * gnulib/lib/.cvsignore: Update. * gnulib/lib/Makefile.am: Update. * gnulib/lib/fseeko.c: Update. * gnulib/lib/getaddrinfo.c: Update. * gnulib/lib/getdelim.c: Update. * gnulib/lib/inet_ntop.c: Update. * gnulib/lib/inet_ntop.h: Update. * gnulib/lib/poll.c: Update. * gnulib/lib/snprintf.c: Update. * gnulib/lib/stdlib.in.h: Update. * gnulib/lib/string.in.h: Update. * gnulib/lib/sys_socket.in.h: Update. * gnulib/lib/sys_stat.in.h: Update. * gnulib/lib/vasnprintf.c: Update. * gnulib/lib/vasprintf.c: Update. * gnulib/lib/wchar.in.h: Update. * gnulib/m4/arpa_inet_h.m4: Update. * gnulib/m4/extensions.m4: Update. * gnulib/m4/gnulib-common.m4: Update. * gnulib/m4/gnulib-comp.m4: Update. * gnulib/m4/include_next.m4: Update. * gnulib/m4/inet_ntop.m4: Update. * gnulib/m4/netinet_in_h.m4: Update. * gnulib/m4/onceonly_2_57.m4: Update. * gnulib/m4/physmem.m4: Update. * gnulib/m4/snprintf.m4: Update. * gnulib/m4/stdint.m4: Update. * gnulib/m4/stdio_h.m4: Update. * gnulib/m4/stdlib_h.m4: Update. * gnulib/m4/string_h.m4: Update. * gnulib/m4/strndup.m4: Update. * gnulib/m4/sys_select_h.m4: Update. * gnulib/m4/sys_socket_h.m4: Update. * gnulib/m4/sys_stat_h.m4: Update. * gnulib/m4/vasnprintf.m4: Update. * gnulib/tests/Makefile.am: Update. * gnulib/tests/test-fseeko.c: Update. * gnulib/tests/test-getaddrinfo.c: Update. * gnulib/tests/test-getdelim.c: Update. * gnulib/tests/test-getline.c: Update. * gnulib/tests/test-lseek.c: Update. * gnulib/tests/test-snprintf.c: Update. * gnulib/tests/test-sys_stat.c: Update. * gnulib/tests/test-vasnprintf.c: Update. * gnulib/tests/test-vasprintf.c: Update.
83 lines
2.9 KiB
Plaintext
83 lines
2.9 KiB
Plaintext
# serial 5 -*- Autoconf -*-
|
|
# Enable extensions on systems that normally disable them.
|
|
|
|
# Copyright (C) 2003, 2006-2008 Free Software Foundation, Inc.
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# This definition of AC_USE_SYSTEM_EXTENSIONS is stolen from CVS
|
|
# Autoconf. Perhaps we can remove this once we can assume Autoconf
|
|
# 2.62 or later everywhere, but since CVS Autoconf mutates rapidly
|
|
# enough in this area it's likely we'll need to redefine
|
|
# AC_USE_SYSTEM_EXTENSIONS for quite some time.
|
|
|
|
# AC_USE_SYSTEM_EXTENSIONS
|
|
# ------------------------
|
|
# Enable extensions on systems that normally disable them,
|
|
# typically due to standards-conformance issues.
|
|
# Remember that #undef in AH_VERBATIM gets replaced with #define by
|
|
# AC_DEFINE. The goal here is to define all known feature-enabling
|
|
# macros, then, if reports of conflicts are made, disable macros that
|
|
# cause problems on some platforms (such as __EXTENSIONS__).
|
|
AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS],
|
|
[AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
|
|
AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
|
|
|
|
AC_CHECK_HEADER([minix/config.h], [MINIX=yes], [MINIX=])
|
|
if test "$MINIX" = yes; then
|
|
AC_DEFINE([_POSIX_SOURCE], [1],
|
|
[Define to 1 if you need to in order for `stat' and other
|
|
things to work.])
|
|
AC_DEFINE([_POSIX_1_SOURCE], [2],
|
|
[Define to 2 if the system does not provide POSIX.1 features
|
|
except with this defined.])
|
|
AC_DEFINE([_MINIX], [1],
|
|
[Define to 1 if on MINIX.])
|
|
fi
|
|
|
|
AH_VERBATIM([__EXTENSIONS__],
|
|
[/* Enable extensions on AIX 3, Interix. */
|
|
#ifndef _ALL_SOURCE
|
|
# undef _ALL_SOURCE
|
|
#endif
|
|
/* Enable GNU extensions on systems that have them. */
|
|
#ifndef _GNU_SOURCE
|
|
# undef _GNU_SOURCE
|
|
#endif
|
|
/* Enable threading extensions on Solaris. */
|
|
#ifndef _POSIX_PTHREAD_SEMANTICS
|
|
# undef _POSIX_PTHREAD_SEMANTICS
|
|
#endif
|
|
/* Enable extensions on HP NonStop. */
|
|
#ifndef _TANDEM_SOURCE
|
|
# undef _TANDEM_SOURCE
|
|
#endif
|
|
/* Enable general extensions on Solaris. */
|
|
#ifndef __EXTENSIONS__
|
|
# undef __EXTENSIONS__
|
|
#endif
|
|
])
|
|
AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
|
|
[ac_cv_safe_to_define___extensions__],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM([[
|
|
# define __EXTENSIONS__ 1
|
|
]AC_INCLUDES_DEFAULT])],
|
|
[ac_cv_safe_to_define___extensions__=yes],
|
|
[ac_cv_safe_to_define___extensions__=no])])
|
|
test $ac_cv_safe_to_define___extensions__ = yes &&
|
|
AC_DEFINE([__EXTENSIONS__])
|
|
AC_DEFINE([_ALL_SOURCE])
|
|
AC_DEFINE([_GNU_SOURCE])
|
|
AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
|
|
AC_DEFINE([_TANDEM_SOURCE])
|
|
])# AC_USE_SYSTEM_EXTENSIONS
|
|
|
|
# gl_USE_SYSTEM_EXTENSIONS
|
|
# ------------------------
|
|
# Enable extensions on systems that normally disable them,
|
|
# typically due to standards-conformance issues.
|
|
AC_DEFUN([gl_USE_SYSTEM_EXTENSIONS],
|
|
[AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])])
|