mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-11-09 23:10:08 +00:00
130426c659
* gnulib/lib/inet_ntop.h: Remove file. * gnulib/m4/onceonly_2_57.m4: Remove file. * build-aux/useless-if-before-free: Update. * build-aux/vc-list-files: Update. * gnulib/lib/.cvsignore: Update. * gnulib/lib/Makefile.am: Update. * gnulib/lib/fseeko.c: Update. * gnulib/lib/getaddrinfo.c: Update. * gnulib/lib/getdelim.c: Update. * gnulib/lib/inet_ntop.c: Update. * gnulib/lib/inet_ntop.h: Update. * gnulib/lib/poll.c: Update. * gnulib/lib/snprintf.c: Update. * gnulib/lib/stdlib.in.h: Update. * gnulib/lib/string.in.h: Update. * gnulib/lib/sys_socket.in.h: Update. * gnulib/lib/sys_stat.in.h: Update. * gnulib/lib/vasnprintf.c: Update. * gnulib/lib/vasprintf.c: Update. * gnulib/lib/wchar.in.h: Update. * gnulib/m4/arpa_inet_h.m4: Update. * gnulib/m4/extensions.m4: Update. * gnulib/m4/gnulib-common.m4: Update. * gnulib/m4/gnulib-comp.m4: Update. * gnulib/m4/include_next.m4: Update. * gnulib/m4/inet_ntop.m4: Update. * gnulib/m4/netinet_in_h.m4: Update. * gnulib/m4/onceonly_2_57.m4: Update. * gnulib/m4/physmem.m4: Update. * gnulib/m4/snprintf.m4: Update. * gnulib/m4/stdint.m4: Update. * gnulib/m4/stdio_h.m4: Update. * gnulib/m4/stdlib_h.m4: Update. * gnulib/m4/string_h.m4: Update. * gnulib/m4/strndup.m4: Update. * gnulib/m4/sys_select_h.m4: Update. * gnulib/m4/sys_socket_h.m4: Update. * gnulib/m4/sys_stat_h.m4: Update. * gnulib/m4/vasnprintf.m4: Update. * gnulib/tests/Makefile.am: Update. * gnulib/tests/test-fseeko.c: Update. * gnulib/tests/test-getaddrinfo.c: Update. * gnulib/tests/test-getdelim.c: Update. * gnulib/tests/test-getline.c: Update. * gnulib/tests/test-lseek.c: Update. * gnulib/tests/test-snprintf.c: Update. * gnulib/tests/test-sys_stat.c: Update. * gnulib/tests/test-vasnprintf.c: Update. * gnulib/tests/test-vasprintf.c: Update.
56 lines
1.6 KiB
Plaintext
56 lines
1.6 KiB
Plaintext
# sys_stat_h.m4 serial 8 -*- Autoconf -*-
|
|
dnl Copyright (C) 2006-2008 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Eric Blake.
|
|
dnl Test whether <sys/stat.h> contains lstat and mkdir or must be substituted.
|
|
|
|
AC_DEFUN([gl_HEADER_SYS_STAT_H],
|
|
[
|
|
AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
|
|
|
|
dnl Check for lstat. Systems that lack it (mingw) also lack symlinks, so
|
|
dnl stat is a good replacement.
|
|
AC_CHECK_FUNCS_ONCE([lstat])
|
|
if test $ac_cv_func_lstat = yes; then
|
|
HAVE_LSTAT=1
|
|
else
|
|
HAVE_LSTAT=0
|
|
fi
|
|
AC_SUBST([HAVE_LSTAT])
|
|
|
|
dnl For the mkdir substitute.
|
|
AC_REQUIRE([AC_C_INLINE])
|
|
|
|
dnl Check for broken stat macros.
|
|
AC_REQUIRE([AC_HEADER_STAT])
|
|
|
|
gl_CHECK_NEXT_HEADERS([sys/stat.h])
|
|
SYS_STAT_H='sys/stat.h'
|
|
AC_SUBST([SYS_STAT_H])
|
|
|
|
dnl Define types that are supposed to be defined in <sys/types.h> or
|
|
dnl <sys/stat.h>.
|
|
AC_CHECK_TYPE([nlink_t], [],
|
|
[AC_DEFINE([nlink_t], [int],
|
|
[Define to the type of st_nlink in struct stat, or a supertype.])],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])
|
|
|
|
]) # gl_HEADER_SYS_STAT_H
|
|
|
|
AC_DEFUN([gl_SYS_STAT_MODULE_INDICATOR],
|
|
[
|
|
dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
|
|
AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
|
|
GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
|
|
])
|
|
|
|
AC_DEFUN([gl_SYS_STAT_H_DEFAULTS],
|
|
[
|
|
dnl Assume proper GNU behavior unless another module says otherwise.
|
|
REPLACE_MKDIR=0; AC_SUBST([REPLACE_MKDIR])
|
|
])
|