mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-08-06 17:03:49 +00:00
492c4628a1
Provide debug log configuration insight in our kbase. There are two modifications of the document compared to the wiki version: 1) The link for reporting a bug agains libvirt was modified to use the gitlab issue tracker. 2) The link to URI specification details is changed to 'https' protocol. Signed-off-by: Peter Krempa <pkrempa@redhat.com> Reviewed-by: Michal Privoznik <mprivozn@redhat.com> Reviewed-by: Ján Tomko <jtomko@redhat.com>
51 lines
1.1 KiB
Meson
51 lines
1.1 KiB
Meson
docs_kbase_files = [
|
|
'backing_chains',
|
|
'debuglogs',
|
|
'domainstatecapture',
|
|
'incrementalbackupinternals',
|
|
'kvm-realtime',
|
|
'launch_security_sev',
|
|
'locking-lockd',
|
|
'locking',
|
|
'locking-sanlock',
|
|
'migrationinternals',
|
|
'qemu-passthrough-security',
|
|
'rpm-deployment',
|
|
's390_protected_virt',
|
|
'secureusage',
|
|
'virtiofs',
|
|
]
|
|
|
|
foreach name : docs_kbase_files
|
|
rst_file = '@0@.rst'.format(name)
|
|
html_file = '@0@.html'.format(name)
|
|
|
|
html_in = docs_rst2html_gen.process(rst_file)
|
|
|
|
out_file = custom_target(
|
|
html_file,
|
|
input: html_in,
|
|
output: html_file,
|
|
command: [
|
|
meson_python_prog,
|
|
python3_prog.path(),
|
|
meson_html_gen_prog.path(),
|
|
xsltproc_prog.path(),
|
|
xmllint_prog.path(),
|
|
meson.build_root(),
|
|
docs_timestamp,
|
|
subsite_xsl,
|
|
'@INPUT@',
|
|
'@OUTPUT@',
|
|
'kbase' / rst_file,
|
|
],
|
|
depends: [ aclperms_gen ],
|
|
depend_files: [ page_xsl ],
|
|
install: true,
|
|
install_dir: docs_html_dir / 'kbase',
|
|
)
|
|
|
|
install_web_deps += out_file
|
|
install_web_files += '@0@:@1@'.format(out_file.full_path(), docs_html_dir / 'kbase')
|
|
endforeach
|