mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2025-03-03 15:43:51 +00:00
642af05e3e
meson wraps python scripts already on win32, so we end up with these failing commands: [185/868] Generating src/rpc/virnetprotocol.h with a custom command FAILED: src/rpc/virnetprotocol.h "sh" "libvirt/scripts/meson-python.sh" "F:/msys64/ucrt64/bin/python3.EXE" "F:/msys64/ucrt64/bin/python.exe" "libvirt/scripts/rpcgen/main.py" "--mode=header" "../src/rpc/virnetprotocol.x" "src/rpc/virnetprotocol.h" SyntaxError: Non-UTF-8 code starting with '\x90' in file F:/msys64/ucrt64/bin/python.exe on line 1, but no encoding declared; see https://peps.python.org/pep-0263/ for details The issue was introduced in a62486b95feed2cf17ce4adbe794a1ecff9ef22a commit. These changes are similar as e06beacec2f8e57bbc5cd8f6eb9d44a1f291966d commit. Signed-off-by: Biswapriyo Nath <nathbappai@gmail.com>
124 lines
2.7 KiB
Meson
124 lines
2.7 KiB
Meson
log_driver_sources = [
|
|
'log_manager.c',
|
|
]
|
|
|
|
log_protocol = 'log_protocol.x'
|
|
|
|
log_protocol_generated = []
|
|
|
|
log_protocol_header_generated = custom_target(
|
|
'log_protocol.h',
|
|
input: log_protocol,
|
|
output: 'log_protocol.h',
|
|
depend_files: rpcgen_src,
|
|
command: [
|
|
rpcgen_prog,
|
|
'--mode=header', '@INPUT@', '@OUTPUT@',
|
|
],
|
|
)
|
|
log_protocol_generated += log_protocol_header_generated
|
|
|
|
log_protocol_generated += custom_target(
|
|
'log_protocol.c',
|
|
input: log_protocol,
|
|
output: 'log_protocol.c',
|
|
depend_files: rpcgen_src,
|
|
command: [
|
|
rpcgen_prog,
|
|
'--mode=source', '--header=log_protocol.h', '@INPUT@', '@OUTPUT@',
|
|
],
|
|
)
|
|
|
|
log_daemon_sources = files(
|
|
'log_daemon.c',
|
|
'log_daemon_config.c',
|
|
'log_daemon_dispatch.c',
|
|
'log_handler.c',
|
|
'log_cleaner.c',
|
|
)
|
|
|
|
if conf.has('WITH_REMOTE')
|
|
log_driver_lib = static_library(
|
|
'virt_log_driver',
|
|
[
|
|
log_driver_sources,
|
|
log_protocol_generated,
|
|
],
|
|
dependencies: [
|
|
rpc_dep,
|
|
src_dep,
|
|
xdr_dep,
|
|
],
|
|
)
|
|
|
|
libvirt_libs += log_driver_lib
|
|
used_sym_files += 'libvirt_logging.syms'
|
|
else
|
|
sym_files += 'libvirt_logging.syms'
|
|
endif
|
|
|
|
if conf.has('WITH_LIBVIRTD')
|
|
log_daemon_generated = custom_target(
|
|
'log_daemon_dispatch_stubs.h',
|
|
input: log_protocol,
|
|
output: 'log_daemon_dispatch_stubs.h',
|
|
command: [
|
|
gendispatch_prog, '--mode=server',
|
|
'virLogManagerProtocol', 'VIR_LOG_MANAGER_PROTOCOL', '@INPUT@',
|
|
],
|
|
capture: true,
|
|
)
|
|
|
|
virt_daemons += {
|
|
'name': 'virtlogd',
|
|
'sources': [
|
|
log_daemon_sources,
|
|
log_daemon_generated,
|
|
log_protocol_generated,
|
|
],
|
|
'include': [
|
|
include_directories('.'),
|
|
],
|
|
}
|
|
|
|
virt_conf_files += files('virtlogd.conf')
|
|
virt_aug_files += files('virtlogd.aug')
|
|
virt_test_aug_files += {
|
|
'name': 'test_virtlogd.aug',
|
|
'aug': files('test_virtlogd.aug.in'),
|
|
'conf': files('virtlogd.conf'),
|
|
'test_name': 'virtlogd',
|
|
'test_srcdir': meson.current_source_dir(),
|
|
'test_builddir': meson.current_build_dir(),
|
|
}
|
|
|
|
virt_daemon_units += {
|
|
'service': 'virtlogd',
|
|
'name': 'logging',
|
|
'service_in': files('virtlogd.service.in'),
|
|
'service_extra_in': [
|
|
files('virtlogd.service.extra.in'),
|
|
systemd_service_oomscoreadjust_extra_in,
|
|
systemd_service_limitnofile_extra_in,
|
|
],
|
|
'sockets': [ 'main', 'admin' ],
|
|
'socket_in': files('virtlogd.socket.in'),
|
|
'socket_admin_in': files('virtlogd-admin.socket.in'),
|
|
'socket_extra_in': [
|
|
files('virtlogd.socket.extra.in'),
|
|
],
|
|
}
|
|
|
|
openrc_init_files += {
|
|
'name': 'virtlogd',
|
|
'in_file': files('virtlogd.init.in'),
|
|
}
|
|
endif
|
|
|
|
log_inc_dir = include_directories('.')
|
|
|
|
log_dep = declare_dependency(
|
|
include_directories: log_inc_dir,
|
|
sources: log_protocol_header_generated,
|
|
)
|