mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-12-22 21:55:25 +00:00
51d5609843
* acinclude.m4: add LIBVIRT_COMPILE_WARNINGS, copied from
GNOME but with a few more flags we'd been using.
* configure.in: use that instead of setting CFLAGS
directly.
* proxy/Makefile.am, python/Makefile.am, qemud/Makefile.am,
src/Makefile.am, tests/Makefile.am: use $(WARN_CFLAGS)
91 lines
2.6 KiB
Plaintext
91 lines
2.6 KiB
Plaintext
dnl
|
|
dnl Taken from gnome-common/macros2/gnome-compiler-flags.m4
|
|
dnl
|
|
dnl We've added:
|
|
dnl -Wextra -Wshadow -Wcast-align -Wwrite-strings -Waggregate-return -Wstrict-prototypes -Winline -Wredundant-decls
|
|
dnl
|
|
AC_DEFUN([LIBVIRT_COMPILE_WARNINGS],[
|
|
dnl ******************************
|
|
dnl More compiler warnings
|
|
dnl ******************************
|
|
|
|
AC_ARG_ENABLE(compile-warnings,
|
|
AC_HELP_STRING([--enable-compile-warnings=@<:@no/minimum/yes/maximum/error@:>@],
|
|
[Turn on compiler warnings]),,
|
|
[enable_compile_warnings="m4_default([$1],[yes])"])
|
|
|
|
warnCFLAGS=
|
|
if test "x$GCC" != xyes; then
|
|
enable_compile_warnings=no
|
|
fi
|
|
|
|
warning_flags=
|
|
realsave_CFLAGS="$CFLAGS"
|
|
|
|
case "$enable_compile_warnings" in
|
|
no)
|
|
warning_flags=
|
|
;;
|
|
minimum)
|
|
warning_flags="-Wall"
|
|
;;
|
|
yes)
|
|
warning_flags="-Wall -Wmissing-prototypes"
|
|
;;
|
|
maximum|error)
|
|
warning_flags="-Wall -Wmissing-prototypes -Wnested-externs -Wpointer-arith"
|
|
warning_flags="$warning_flags -Wextra -Wshadow -Wcast-align -Wwrite-strings -Waggregate-return -Wstrict-prototypes -Winline -Wredundant-decls"
|
|
CFLAGS="$warning_flags $CFLAGS"
|
|
for option in -Wno-sign-compare; do
|
|
SAVE_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS $option"
|
|
AC_MSG_CHECKING([whether gcc understands $option])
|
|
AC_TRY_COMPILE([], [],
|
|
has_option=yes,
|
|
has_option=no,)
|
|
CFLAGS="$SAVE_CFLAGS"
|
|
AC_MSG_RESULT($has_option)
|
|
if test $has_option = yes; then
|
|
warning_flags="$warning_flags $option"
|
|
fi
|
|
unset has_option
|
|
unset SAVE_CFLAGS
|
|
done
|
|
unset option
|
|
if test "$enable_compile_warnings" = "error" ; then
|
|
warning_flags="$warning_flags -Werror"
|
|
fi
|
|
;;
|
|
*)
|
|
AC_MSG_ERROR(Unknown argument '$enable_compile_warnings' to --enable-compile-warnings)
|
|
;;
|
|
esac
|
|
CFLAGS="$realsave_CFLAGS"
|
|
AC_MSG_CHECKING(what warning flags to pass to the C compiler)
|
|
AC_MSG_RESULT($warning_flags)
|
|
|
|
AC_ARG_ENABLE(iso-c,
|
|
AC_HELP_STRING([--enable-iso-c],
|
|
[Try to warn if code is not ISO C ]),,
|
|
[enable_iso_c=no])
|
|
|
|
AC_MSG_CHECKING(what language compliance flags to pass to the C compiler)
|
|
complCFLAGS=
|
|
if test "x$enable_iso_c" != "xno"; then
|
|
if test "x$GCC" = "xyes"; then
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-ansi[\ \ ]*) ;;
|
|
*) complCFLAGS="$complCFLAGS -ansi" ;;
|
|
esac
|
|
case " $CFLAGS " in
|
|
*[\ \ ]-pedantic[\ \ ]*) ;;
|
|
*) complCFLAGS="$complCFLAGS -pedantic" ;;
|
|
esac
|
|
fi
|
|
fi
|
|
AC_MSG_RESULT($complCFLAGS)
|
|
|
|
WARN_CFLAGS="$warning_flags $complCFLAGS"
|
|
AC_SUBST(WARN_CFLAGS)
|
|
])
|