mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-07-31 14:07:16 +00:00
5bdcef13d1
Currently the libxl driver claims support for Xen >= 4.4, but Xen 4.4 and 4.5 are no longer supported upstream. Let's increase the minimum supported Xen version to 4.6 and change the defined LIBXL_API_VERSION to 0x040500, which is the API version defined when Xen 4.6 was released. Since Xen 4.6 contains a pkgconfig file, drop the now unused code that falls back to using LIBVIRT_CHECK_LIB in the absence of pkgconfig file. In addition, bumping the LIBXL_API_VERSION required adjusting the calls to libxl_set_vcpuaffinity to account for the extra parameter in the 0x040500 version of the API. Signed-off-by: Jim Fehlig <jfehlig@suse.com> Reviewed-by: Ján Tomko <jtomko@redhat.com>
79 lines
2.6 KiB
Plaintext
79 lines
2.6 KiB
Plaintext
dnl The libxl driver
|
|
dnl
|
|
dnl Copyright (C) 2016 Red Hat, Inc.
|
|
dnl
|
|
dnl This library is free software; you can redistribute it and/or
|
|
dnl modify it under the terms of the GNU Lesser General Public
|
|
dnl License as published by the Free Software Foundation; either
|
|
dnl version 2.1 of the License, or (at your option) any later version.
|
|
dnl
|
|
dnl This library is distributed in the hope that it will be useful,
|
|
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
dnl Lesser General Public License for more details.
|
|
dnl
|
|
dnl You should have received a copy of the GNU Lesser General Public
|
|
dnl License along with this library. If not, see
|
|
dnl <http://www.gnu.org/licenses/>.
|
|
dnl
|
|
|
|
AC_DEFUN([LIBVIRT_DRIVER_ARG_LIBXL], [
|
|
LIBVIRT_ARG_WITH_FEATURE([LIBXL], [libxenlight], [check])
|
|
])
|
|
|
|
AC_DEFUN([LIBVIRT_DRIVER_CHECK_LIBXL], [
|
|
LIBXL_LIBS=""
|
|
LIBXL_CFLAGS=""
|
|
LIBXL_FIRMWARE_DIR=""
|
|
LIBXL_EXECBIN_DIR=""
|
|
LIBXL_API_VERSION="-DLIBXL_API_VERSION=0x040500"
|
|
|
|
dnl search for libxl, aka libxenlight
|
|
LIBVIRT_CHECK_PKG([LIBXL], [xenlight], [4.6.0])
|
|
if test "x$with_libxl" = "xyes" ; then
|
|
LIBXL_FIRMWARE_DIR=$($PKG_CONFIG --variable xenfirmwaredir xenlight)
|
|
LIBXL_EXECBIN_DIR=$($PKG_CONFIG --variable libexec_bin xenlight)
|
|
|
|
old_LIBS="$LIBS"
|
|
old_CFLAGS="$CFLAGS"
|
|
|
|
LIBXL_CFLAGS="$LIBXL_CFLAGS $LIBXL_API_VERSION"
|
|
|
|
dnl If building with libxl, use the libxl utility header and lib too
|
|
AC_CHECK_HEADERS([libxlutil.h])
|
|
LIBXL_LIBS="$LIBXL_LIBS -lxlutil"
|
|
if test "x$LIBXL_FIRMWARE_DIR" != "x"; then
|
|
AC_DEFINE_UNQUOTED([LIBXL_FIRMWARE_DIR], ["$LIBXL_FIRMWARE_DIR"], [directory containing Xen firmware blobs])
|
|
fi
|
|
if test "x$LIBXL_EXECBIN_DIR" != "x"; then
|
|
AC_DEFINE_UNQUOTED([LIBXL_EXECBIN_DIR], ["$LIBXL_EXECBIN_DIR"], [directory containing Xen libexec binaries])
|
|
fi
|
|
dnl Check if the xtl_* infrastructure is in libxentoollog
|
|
dnl (since Xen 4.7) if not then assume it is in libxenctrl
|
|
dnl (as it was for 4.6 and earler)
|
|
AC_CHECK_LIB([xentoollog], [xtl_createlogger_stdiostream], [
|
|
LIBXL_LIBS="$LIBXL_LIBS -lxenstore -lxentoollog"
|
|
],[
|
|
LIBXL_LIBS="$LIBXL_LIBS -lxenstore -lxenctrl"
|
|
])
|
|
|
|
dnl Check if libxl_domain_config_from_json is available for domXML to
|
|
dnl libxl_domain_config tests
|
|
LIBS="$LIBS -lxenlight -lxenctrl"
|
|
AC_CHECK_FUNCS([libxl_domain_config_from_json])
|
|
CFLAGS="$old_CFLAGS"
|
|
LIBS="$old_LIBS"
|
|
fi
|
|
|
|
AC_SUBST([LIBXL_CFLAGS])
|
|
AC_SUBST([LIBXL_LIBS])
|
|
])
|
|
|
|
AC_DEFUN([LIBVIRT_RESULT_LIBXL], [
|
|
LIBVIRT_RESULT_LIB([LIBXL])
|
|
])
|
|
|
|
AC_DEFUN([LIBVIRT_DRIVER_RESULT_LIBXL], [
|
|
LIBVIRT_RESULT([libxl], [$with_libxl])
|
|
])
|