mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-08-27 19:11:16 +00:00
* build-aux/mktempd (rand_bytes, mktempd): * build-aux/useless-if-before-free (FILE): * build-aux/vc-list-files: * gnulib/lib/.cvsignore: * gnulib/lib/Makefile.am: * gnulib/lib/poll.c (poll): * gnulib/lib/stdbool.in.h (_GL_STDBOOL_H, true): * gnulib/lib/stdio-impl.h (fp_, fp_ub): * gnulib/lib/stdio.in.h (vasprintf, obstack_printf) (obstack_vprintf): * gnulib/lib/vasnprintf.c (_GNU_SOURCE, sprintf, IF_LINT, exp) (remainder, scale10_round_decimal_long_double) (scale10_round_decimal_double, pad_ourselves): * gnulib/m4/gnulib-cache.m4: * gnulib/m4/gnulib-common.m4 (gl_MODULE_INDICATOR): * gnulib/m4/gnulib-tool.m4 (gl_LOCAL_DIR, gl_M4_BASE, gl_PO_BASE) (gl_DOC_BASE, gl_TESTS_BASE, gl_WITH_TESTS, gl_LIB, gl_LGPL) (gl_MAKEFILE_NAME, gl_MACRO_PREFIX, gl_PO_DOMAIN, gl_VC_FILES): * gnulib/m4/lock.m4 (gl_LOCK_EARLY_BODY, gl_PREREQ_LOCK) (gl_DISABLE_THREADS): * gnulib/m4/onceonly.m4: * gnulib/m4/posix-shell.m4 (gl_POSIX_SHELL): * gnulib/m4/stdio_h.m4 (gl_STDIO_H_DEFAULTS): * gnulib/tests/test-getaddrinfo.c (ENABLE_DEBUGGING, dbgprintf) (simple): * gnulib/tests/test-stdint.c (UINTMAX_MAX, or): * gnulib/tests/test-vc-list-files-cvs.sh (compare): * gnulib/tests/test-vc-list-files-git.sh (compare):
181 lines
5.0 KiB
Perl
Executable File
181 lines
5.0 KiB
Perl
Executable File
#!/usr/bin/perl -T
|
|
# Detect instances of "if (p) free (p);".
|
|
# Likewise for "if (p != NULL) free (p);". And with braces.
|
|
|
|
my $VERSION = '2008-05-25 17:36'; # UTC
|
|
# The definition above must lie within the first 8 lines in order
|
|
# for the Emacs time-stamp write hook (at end) to update it.
|
|
# If you change this file with Emacs, please let the write hook
|
|
# do its job. Otherwise, update this string manually.
|
|
|
|
# Copyright (C) 2008 Free Software Foundation, Inc.
|
|
|
|
# This program is free software: you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation, either version 3 of the License, or
|
|
# (at your option) any later version.
|
|
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
# Written by Jim Meyering
|
|
|
|
use strict;
|
|
use warnings;
|
|
use Getopt::Long;
|
|
|
|
(my $ME = $0) =~ s|.*/||;
|
|
|
|
# use File::Coda; # http://meyering.net/code/Coda/
|
|
END {
|
|
defined fileno STDOUT or return;
|
|
close STDOUT and return;
|
|
warn "$ME: failed to close standard output: $!\n";
|
|
$? ||= 1;
|
|
}
|
|
|
|
sub usage ($)
|
|
{
|
|
my ($exit_code) = @_;
|
|
my $STREAM = ($exit_code == 0 ? *STDOUT : *STDERR);
|
|
if ($exit_code != 0)
|
|
{
|
|
print $STREAM "Try `$ME --help' for more information.\n";
|
|
}
|
|
else
|
|
{
|
|
print $STREAM <<EOF;
|
|
Usage: $ME [OPTIONS] FILE...
|
|
|
|
Detect any instance in FILE of a useless "if" test before a free call, e.g.,
|
|
"if (p) free (p);". Any such test may be safely removed without affecting
|
|
the semantics of the C code in FILE. Use --name=FOO --name=BAR to also
|
|
detect free-like functions named FOO and BAR.
|
|
|
|
OPTIONS:
|
|
|
|
--list print only the name of each matching FILE (\0-terminated)
|
|
--name=N add name N to the list of `free'-like functions to detect;
|
|
may be repeated
|
|
|
|
--help display this help and exit
|
|
--version output version information and exit
|
|
|
|
Exit status:
|
|
|
|
0 one or more matches
|
|
1 no match
|
|
2 an error
|
|
|
|
EXAMPLE:
|
|
|
|
For example, this command prints all removable "if" tests before "free"
|
|
and "kfree" calls in the linux kernel sources:
|
|
|
|
git ls-files -z |xargs -0 $ME --name=kfree
|
|
|
|
EOF
|
|
}
|
|
exit $exit_code;
|
|
}
|
|
|
|
{
|
|
sub EXIT_MATCH {0}
|
|
sub EXIT_NO_MATCH {1}
|
|
sub EXIT_ERROR {2}
|
|
my $err = EXIT_NO_MATCH;
|
|
|
|
my $list;
|
|
my @name = qw(free);
|
|
GetOptions
|
|
(
|
|
help => sub { usage 0 },
|
|
version => sub { print "$ME version $VERSION\n"; exit },
|
|
list => \$list,
|
|
'name=s@' => \@name,
|
|
) or usage 1;
|
|
|
|
# Make sure we have the right number of non-option arguments.
|
|
# Always tell the user why we fail.
|
|
@ARGV < 1
|
|
and (warn "$ME: missing FILE argument\n"), usage EXIT_ERROR;
|
|
|
|
my $or = join '|', @name;
|
|
my $regexp = qr/(?:$or)/;
|
|
|
|
# Set the input record separator.
|
|
# Note: this makes it impractical to print line numbers.
|
|
$/ = '"';
|
|
|
|
my $found_match = 0;
|
|
FILE:
|
|
foreach my $file (@ARGV)
|
|
{
|
|
open FH, '<', $file
|
|
or (warn "$ME: can't open `$file' for reading: $!\n"),
|
|
$err = EXIT_ERROR, next;
|
|
while (defined (my $line = <FH>))
|
|
{
|
|
while ($line =~
|
|
/\b(if\s*\(\s*([^)]+?)(?:\s*!=\s*NULL)?\s*\)
|
|
(?: \s*$regexp\s*\((?:\s*\([^)]+\))?\s*([^)]+)\)|
|
|
\s*\{\s*$regexp\s*\((?:\s*\([^)]+\))?\s*([^)]+)\)\s*;\s*\}))/sxg)
|
|
{
|
|
# Compare "if" expression and free'd expression,
|
|
# without regard to white space.
|
|
(my $e1 = $2) =~ tr/ \t//d;
|
|
my $e2 = defined $3 ? $3 : $4;
|
|
$e2 =~ tr/ \t//d;
|
|
if ($e1 eq $e2)
|
|
{
|
|
$found_match = 1;
|
|
$list
|
|
and (print "$file\0"), next FILE;
|
|
print "$file: $1\n";
|
|
}
|
|
}
|
|
}
|
|
}
|
|
continue
|
|
{
|
|
close FH;
|
|
}
|
|
|
|
$found_match && $err == EXIT_NO_MATCH
|
|
and $err = EXIT_MATCH;
|
|
|
|
exit $err;
|
|
}
|
|
|
|
my $foo = <<'EOF';
|
|
# The above is to *find* them.
|
|
# This adjusts them, removing the unnecessary "if (p)" part.
|
|
|
|
# FIXME: do something like this as an option (doesn't do braces):
|
|
useless-if-before-free -l $(lid -knone free) | xargs -0 \
|
|
perl -0x3b -pi -e \
|
|
's/\bif\s*\(\s*(\S+?)(?:\s*!=\s*NULL)?\s*\)\s+(free\s*\((?:\s*\([^)]+\))?\s*\1\s*\))/$2/s'
|
|
|
|
# Or, with git:
|
|
git ls-files -z |xargs -0 perl -0x3b -pi -e '...'
|
|
|
|
Be careful that the result of the above transformation is valid.
|
|
If the matched string is followed by "else", then obviously, it won't be.
|
|
|
|
When modifying files, refuse to process anything other than a regular file.
|
|
EOF
|
|
|
|
## Local Variables:
|
|
## indent-tabs-mode: nil
|
|
## eval: (add-hook 'write-file-hooks 'time-stamp)
|
|
## time-stamp-start: "my $VERSION = '"
|
|
## time-stamp-format: "%:y-%02m-%02d %02H:%02M"
|
|
## time-stamp-time-zone: "UTC"
|
|
## time-stamp-end: "'; # UTC"
|
|
## End:
|